home *** CD-ROM | disk | FTP | other *** search
/ Languguage OS 2 / Languguage OS II Version 10-94 (Knowledge Media)(1994).ISO / gnu / smaltalk.lha / smalltalk-1.1.1 / Collection.st < prev    next >
Text File  |  1991-09-12  |  7KB  |  267 lines
  1. "======================================================================
  2. |
  3. |   Collection Method Definitions
  4. |
  5.  ======================================================================"
  6.  
  7.  
  8. "======================================================================
  9. |
  10. | Copyright (C) 1990, 1991 Free Software Foundation, Inc.
  11. | Written by Steve Byrne.
  12. |
  13. | This file is part of GNU Smalltalk.
  14. |
  15. | GNU Smalltalk is free software; you can redistribute it and/or modify it
  16. | under the terms of the GNU General Public License as published by the Free
  17. | Software Foundation; either version 1, or (at your option) any later version.
  18. | 
  19. | GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
  20. | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  21. | FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  22. | details.
  23. | 
  24. | You should have received a copy of the GNU General Public License along with
  25. | GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
  26. | Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  
  27. |
  28.  ======================================================================"
  29.  
  30.  
  31. "
  32. |     Change Log
  33. | ============================================================================
  34. | Author       Date       Change 
  35. | sbb         12 Sep 91      Changed printOn: to recursively call printOn:
  36. |
  37. | sbb         12 Sep 91      Fix detect: method to return the value
  38. |
  39. | sbyrne     25 Apr 89      created.
  40. |
  41. "
  42.  
  43. Object subclass: #Collection
  44.        instanceVariableNames: ''
  45.        classVariableNames: ''
  46.        poolDictionaries: ''
  47.        category: nil.
  48.  
  49. Collection comment: 
  50. 'I am an abstract class.  My instances are collections of objects.  My
  51. subclasses may place some restrictions or add some definitions to how
  52. the objects are stored or organized; I say nothing about this.  I merely
  53. provide some object creation and access routines for general collections
  54. of objects.' !
  55.  
  56.  
  57. !Collection class methodsFor: 'instance creation'!
  58.  
  59. with: anObject
  60.     ^self new add: anObject; yourself
  61. !
  62.  
  63. with: firstObject with: secondObject
  64.     ^self new add: firstObject; add: secondObject; yourself
  65. !
  66.  
  67. with: firstObject with: secondObject with: thirdObject
  68.     ^self new add: firstObject; add: secondObject; add: thirdObject; yourself
  69. !
  70.  
  71. with: firstObject with: secondObject with: thirdObject with: fourthObject
  72.     ^self new add: firstObject; add: secondObject; add: thirdObject;
  73.         add: fourthObject; yourself
  74. !!
  75.  
  76.  
  77.  
  78. !Collection methodsFor: 'Adding to a collection'!
  79.  
  80. add: newObject
  81.     self subclassResponsibility
  82. !
  83.  
  84. addAll: aCollection
  85.     aCollection do: [ :element | self add: element ].
  86.     ^aCollection
  87. !!
  88.  
  89.  
  90.  
  91. !Collection methodsFor: 'Removing from a collection'!
  92.  
  93. remove: oldObject ifAbsent: anExceptionBlock
  94.     self subclassResponsibility
  95. !
  96.  
  97. remove: oldObject
  98.     self remove: oldObject
  99.          ifAbsent: [ ^self error: 'Failed to remove object' ].
  100.     ^oldObject
  101. !
  102.  
  103. removeAll: aCollection
  104.     " ??? we're supposed to report an error if an object can't be removed
  105.       properly.  I've elected to let remove: report the error.  Also, it's
  106.       not clear whether we're supposed to remove all occurrences of the
  107.       members of aCollection from the receiver, or only the first."
  108.     aCollection do: [ :element | self remove: element ].
  109.     ^aCollection
  110. !!
  111.  
  112.  
  113.  
  114. !Collection methodsFor: 'testing collections'!
  115.  
  116. includes: anObject
  117.     self do: [ :element | anObject = element ifTrue: [ ^true ] ].
  118.     ^false
  119. !
  120.  
  121. isEmpty
  122.     ^self size == 0
  123. !
  124.  
  125. occurrencesOf: anObject
  126.     | count |
  127.     count _ 0.
  128.     self do: [ :element | anObject == element ifTrue: [ count _ count + 1 ] ].
  129.     ^count
  130. !
  131.  
  132. size
  133.     | count |
  134.     count _ 0.
  135.     self do: [ :element | count _ count + 1].
  136.     ^count
  137. !!
  138.  
  139.  
  140.  
  141. !Collection methodsFor: 'enumerating the elements of a collection'!
  142.  
  143. do: aBlock
  144.     self subclassResponsibility
  145. !
  146.  
  147. select: aBlock
  148.     | newCollection |
  149.     " ### I don't know if this is the right way to create a new collection
  150.       in all cases...I suspect that it is not..."
  151.     newCollection _ self species new.
  152.     self do: [ :element | (aBlock value: element)
  153.                             ifTrue: [ newCollection add: element ]
  154.          ].
  155.     ^newCollection
  156. !
  157.  
  158. reject: aBlock
  159.     | newCollection |
  160.     " ### I don't know if this is the right way to create a new collection
  161.       in all cases...I suspect that it is not..."
  162.     newCollection _ self species new.
  163.     self do: [ :element | (aBlock value: element)
  164.                             ifFalse: [ newCollection add: element ]
  165.          ].
  166.     ^newCollection
  167. !
  168.  
  169. collect: aBlock
  170.     | newCollection |
  171.     " ### I don't know if this is the right way to create a new collection
  172.       in all cases...I suspect that it is not..."
  173.     newCollection _ self species new.
  174.     self do: [ :element | newCollection add: (aBlock value: element) ].
  175.     ^newCollection
  176. !
  177.  
  178. detect: aBlock ifNone: exceptionBlock
  179.     self do: [ :element | (aBlock value: element) ifTrue: [ ^element ] ].
  180.     exceptionBlock value    
  181. !
  182.     
  183. detect: aBlock
  184.     ^self detect: aBlock ifNone: [ ^self error: 'Collection detect: failed']
  185. !
  186.  
  187. inject: thisValue into: binaryBlock
  188.     self do: [ :element | thisValue _ binaryBlock value: thisValue
  189.                                                   value: element ].
  190.     ^thisValue
  191. !!
  192.  
  193.  
  194.  
  195. !Collection methodsFor: 'converting'!
  196.  
  197. asBag
  198.     | aBag |
  199.     aBag _ Bag new.
  200.     self do: [ :element | aBag add: element ].
  201.     ^aBag
  202. !
  203.  
  204. asSet
  205.     | aSet |
  206.     aSet _ Set new: self size.
  207.     self do: [ :element | aSet add: element ].
  208.     ^aSet
  209. !
  210.  
  211. asOrderedCollection
  212.     | anOrderedCollection |
  213.     anOrderedCollection _ OrderedCollection new: self size.
  214.     self do: [ :element | anOrderedCollection add: element ].
  215.     ^anOrderedCollection
  216. !
  217.  
  218. asSortedCollection
  219.     | aSortedCollection |
  220.     aSortedCollection _ SortedCollection new.
  221.     self do: [ :element | aSortedCollection add: element ].
  222.     ^aSortedCollection
  223. !
  224.  
  225. asSortedCollection: aBlock
  226.     | aSortedCollection |
  227.     aSortedCollection _ SortedCollection sortBlock: aBlock.
  228.     self do: [ :element | aSortedCollection add: element ].
  229.     ^aSortedCollection
  230. !!
  231.  
  232.  
  233.  
  234. !Collection methodsFor: 'printing'!
  235.  
  236. printOn: aStream
  237.     | firstTime |
  238.     firstTime _ true.
  239.     aStream nextPutAll: self classNameString.
  240.     aStream nextPutAll: ' ('.
  241.     self do:
  242.         [ :element | firstTime ifTrue: [ firstTime _ false ]
  243.                            ifFalse: [ aStream nextPut: Character space ].
  244.               element printOn: aStream ].
  245.     aStream nextPut: $)
  246. !!
  247.  
  248.  
  249.  
  250. !Collection methodsFor: 'storing'!
  251.  
  252. store: aStream
  253.     | noElements |
  254.     aStream nextPut: $(.
  255.     aStream nextPutAll: self classNameString.
  256.     aStream nextPutAll: ' new'.
  257.     noElements _ true.
  258.     self do:
  259.         [ :element | aStream nextPutAll: ' add: '.
  260.                      element storeOn: aStream.
  261.              aStream nextPut: $;.
  262.              noElements _ false ].
  263.     noElements ifFalse: [ aStream nextPutAll: ' yourself' ].
  264.     aStream nextPut: $)
  265. !!
  266.  
  267.